peon/src/backend/vm.nim

# Copyright 2022 Mattia Giambirtone & All Contributors
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#    http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

## The Peon runtime environment
import types
import ../config
import ../frontend/meta/bytecode


type
    PeonVM* = ref object
        ## The Peon Virtual Machine
        stack: seq[PeonObject]
        ip: int                     # Instruction pointer
        sp: int                     # Stack pointer
        cache: array[6, PeonObject] # Singletons cache
        chunk: Chunk                # Piece of bytecode to execute


proc initCache*(self: PeonVM) =
    ## Initializes the VM's
    ## singletons cache
    self.cache[0] = PeonObject(kind: Nil)
    self.cache[1] = PeonObject(kind: Bool, boolean: true)
    self.cache[2] = PeonObject(kind: Bool, boolean: false)
    self.cache[3] = PeonObject(kind: ObjectKind.Inf, positive: true)
    self.cache[4] = PeonObject(kind: ObjectKind.Inf, positive: false)
    self.cache[5] = PeonObject(kind: ObjectKind.Nan)


proc newPeonVM*: PeonVM =
    ## Initializes a new, blank VM
    ## for executing Peon bytecode
    new(result)
    result.ip = 0
    result.sp = 0
    result.stack = newSeqOfCap[PeonObject](INITIAL_STACK_SIZE)
    result.initCache()
    for _ in 0..<INITIAL_STACK_SIZE:
        result.stack.add(result.cache[0])

## Getters for singleton types (they are cached!)

proc getNil*(self: PeonVM): PeonObject = self.cache[0]

proc getBool*(self: PeonVM, value: bool): PeonObject =
    if value:
        return self.cache[1]
    return self.cache[2]

proc getInf*(self: PeonVM, positive: bool): PeonObject =
    if positive:
        return self.cache[3]
    return self.cache[4]

proc getNan*(self: PeonVM): PeonObject = self.cache[5]

## Stack primitives

proc push(self: PeonVM, obj: PeonObject) =
    ## Pushes a Peon object onto the
    ## stack
    if self.sp >= self.stack.high():
        for _ in 0..self.stack.len():
            self.stack.add(self.getNil())
    self.stack[self.sp] = obj
    inc(self.sp)


proc pop(self: PeonVM): PeonObject =
    ## Pops a Peon object off the
    ## stack, decreasing the stack
    ## pointer. The object is returned
    dec(self.sp)
    return self.stack[self.sp]


proc peek(self: PeonVM): PeonObject =
    ## Returns the element at the top
    ## of the stack without consuming
    ## it
    return self.stack[self.sp]


proc readByte(self: PeonVM): uint8 =
    ## Reads a single byte from the
    ## bytecode and returns it as an
    ## unsigned 8 bit integer
    inc(self.ip)
    return self.chunk.code[self.ip - 1]


proc readShort(self: PeonVM): uint16 =
    ## Reads two bytes from the
    ## bytecode and returns them
    ## as an unsigned 16 bit
    ## integer
    var arr: array[2, uint8] = [self.readByte(), self.readByte()]
    copyMem(result.addr, unsafeAddr(arr), sizeof(arr))


proc readLong(self: PeonVM): uint32 =
    ## Reads three bytes from the
    ## bytecode and returns them
    ## as an unsigned 32 bit
    ## integer. Note however that
    ## the boundary is capped at
    ## 24 bits instead of 32
    var arr: array[3, uint8] = [self.readByte(), self.readByte(), self.readByte()]
    copyMem(result.addr, unsafeAddr(arr), sizeof(arr))


proc readInt64(self: PeonVM, idx: int): PeonObject =
    ## Reads a constant from the
    ## chunk's constant table and
    ## returns a Peon object. Assumes
    ## the constant is an Int64
    var arr = [self.chunk.byteConsts[idx], self.chunk.byteConsts[idx + 1],
            self.chunk.byteConsts[idx + 2], self.chunk.byteConsts[idx + 3]]
    result = PeonObject(kind: Int64)
    copyMem(result.long.addr, arr.addr, sizeof(arr))


proc readUInt64(self: PeonVM, idx: int): PeonObject =
    ## Reads a constant from the
    ## chunk's constant table and
    ## returns a Peon object. Assumes
    ## the constant is an UInt64
    var arr = [self.chunk.byteConsts[idx], self.chunk.byteConsts[idx + 1],
            self.chunk.byteConsts[idx + 2], self.chunk.byteConsts[idx + 3]]
    result = PeonObject(kind: UInt64)
    copyMem(result.uLong.addr, arr.addr, sizeof(arr))


proc dispatch*(self: PeonVM) =
    ## Main bytecode dispatch loop
    var instruction: OpCode
    while true:
        instruction = OpCode(self.readByte())
        case instruction:
            of LoadTrue:
                self.push(self.getBool(true))
            of LoadFalse:
                self.push(self.getBool(false))
            of LoadNan:
                self.push(self.getNan())
            of LoadNil:
                self.push(self.getNil())
            of LoadInf:
                self.push(self.getInf(true))
            of LoadInt64:
                self.push(self.readInt64(int(self.readLong())))
            of LoadUInt64:
                self.push(self.readUInt64(int(self.readLong())))
            of OpCode.Return:
                # TODO
                return
            of NoOp:
                continue
            of Pop:
                discard self.pop()
            of Jump:
                self.ip = int(self.readShort())
            of JumpForwards:
                self.ip += int(self.readShort())
            of JumpBackwards:
                self.ip -= int(self.readShort())
            of JumpIfFalse:
                if not self.peek().boolean:
                    self.ip += int(self.readShort())
            of JumpIfTrue:
                if self.peek().boolean:
                    self.ip += int(self.readShort())
            of JumpIfFalsePop:
                if not self.peek().boolean:
                    self.ip += int(self.readShort())
                discard self.pop()
            of JumpIfFalseOrPop:
                if not self.peek().boolean:
                    self.ip += int(self.readShort())
                else:
                    discard self.pop()
            of LongJumpIfFalse:
                if not self.peek().boolean:
                    self.ip += int(self.readLong())
            of LongJumpIfFalsePop:
                if not self.peek().boolean:
                    self.ip += int(self.readLong())
                discard self.pop()
            of LongJumpForwards:
                self.ip += int(self.readLong())
            of LongJumpBackwards:
                self.ip -= int(self.readLong())
            of LongJump:
                self.ip = int(self.readLong())
            of LongJumpIfFalseOrPop:
                if not self.peek().boolean:
                    self.ip += int(self.readLong())
                else:
                    discard self.pop()
            else:
                discard


proc run*(self: PeonVM, chunk: Chunk) =
    ## Executes a piece of Peon bytecode.
    self.chunk = chunk
    self.sp = 0
    self.ip = 0
    self.dispatch()