CPG/src/Chess/board.nim

# Copyright 2023 Mattia Giambirtone & All Contributors
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#    http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
import ../util/matrix

export matrix

import std/strutils
import std/strformat
import std/sequtils

type

    PieceColor* = enum
        ## A piece color enumeration
        None = 0'i8,
        White, 
        Black

    PieceKind* = enum
        ## A chess piece enumeration
        Empty = 0'i8,    # No piece
        Bishop = 'b', 
        King = 'k'
        Knight = 'n',
        Pawn = 'p', 
        Queen = 'q',
        Rook = 'r', 

    Piece* = object
        ## A chess piece
        color*: PieceColor
        kind*: PieceKind

    MoveFlag* = enum
        ## An enumeration of move flags
        Default = 0'i8, # No flag
        EnPassant,      # Move is a capture with en passant
        Capture,        # Move is a capture
        DoublePush,     # Move is a double pawn push
        # Castling metadata
        CastleLong,
        CastleShort,
        # Pawn promotion metadata
        PromoteToQueen,
        PromoteToRook,
        PromoteToBishop,
        PromoteToKnight       

    # Useful type aliases
    Location* = tuple[row, col: int8]
    
    Attacked = seq[tuple[source, target: Location]]
    Pinned = seq[tuple[source, target, direction: Location]]

    Pieces = tuple[king: Location, queens: seq[Location], rooks: seq[Location],
                   bishops: seq[Location], knights: seq[Location],
                   pawns: seq[Location]]
    
    CountData = tuple[nodes: uint64, captures: uint64, castles: uint64, checks: uint64,  promotions: uint64, enPassant: uint64, checkmates: uint64]

    Move* = object
        ## A chess move
        piece*: Piece
        startSquare*: Location
        targetSquare*: Location
        flag*: MoveFlag

    Position* = ref object
        ## A chess position
        move: Move
        # Did the rooks on either side/the king move?
        castlingAvailable: tuple[white, black: tuple[queen, king: bool]]
        # Number of half-moves that were performed
        # to reach this position starting from the
        # root of the tree
        plyFromRoot: int16
        # Number of half moves since
        # last piece capture or pawn movement.
        # Used for the 50-move rule
        halfMoveClock: int8
        # Full move counter. Increments
        # every 2 ply
        fullMoveCount: int16
        # En passant target square (see https://en.wikipedia.org/wiki/En_passant)
        enPassantSquare*: Move
        # Locations of all pieces
        pieces: tuple[white: Pieces, black: Pieces]
        # Potential attacking moves for black and white
        attacked: tuple[white: Attacked, black: Attacked]
        pinned: tuple[white: Pinned, black: Pinned]
        # Has any piece been captured to reach this position?
        captured: Piece
        # Active color
        turn: PieceColor


    ChessBoard* = ref object
        ## A chess board object
        grid: Matrix[Piece]
        position: Position
        # List of reached positions
        positions: seq[Position]


# Initialized only once, copied every time
var empty: seq[Piece] = @[]
for _ in countup(0, 63):
    empty.add(Piece(kind: Empty, color: None))


func emptyPiece*: Piece {.inline.} = Piece(kind: Empty, color: None)
func emptyLocation*: Location {.inline.} = (-1 , -1)
func opposite*(c: PieceColor): PieceColor {.inline.} = (if c == White: Black else: White)
proc algebraicToLocation*(s: string): Location {.inline.}
proc makeMove*(self: ChessBoard, startSquare, targetSquare: string): Move {.discardable.}
proc makeMove*(self: ChessBoard, move: Move): Move {.discardable.}
proc makeMove*(self: ChessBoard, startSquare, targetSquare: Location): Move {.discardable.}
func emptyMove*: Move {.inline.} = Move(startSquare: emptyLocation(), targetSquare: emptyLocation(), piece: emptyPiece())
func `+`*(a, b: Location): Location = (a.row + b.row, a.col + b.col)
func `-`*(a: Location): Location = (-a.row, -a.col)
func `-`*(a, b: Location): Location = (a.row - b.row, a.col - b.col)
func isValid*(a: Location): bool {.inline.} = a.row in 0..7 and a.col in 0..7
proc generateMoves(self: ChessBoard, location: Location): seq[Move]
proc isAttacked*(self: ChessBoard, loc: Location, color: PieceColor = None): bool
proc undoMove*(self: ChessBoard, move: Move)
proc isLegal(self: ChessBoard, move: Move): bool {.inline.}
proc doMove(self: ChessBoard, move: Move)
proc pretty*(self: ChessBoard): string
proc spawnPiece(self: ChessBoard, location: Location, piece: Piece)
proc updateAttackedSquares(self: ChessBoard)
proc getPinnedDirections(self: ChessBoard, loc: Location): seq[Location]


proc extend[T](self: var seq[T], other: openarray[T]) {.inline.} = 
    for x in other:
        self.add(x)


# Due to our board layout, directions of movement are reversed for white/black so
# we need these helpers to avoid going mad with integer tuples and minus signs
# everywhere
func topLeftDiagonal(color: PieceColor): Location {.inline.} = (if color == White: (-1, -1) else: (1, 1))
func topRightDiagonal(color: PieceColor): Location {.inline.} = (if color == White: (-1, 1) else: (1, -1))
func bottomLeftDiagonal(color: PieceColor): Location {.inline.} = (if color == White: (1, -1) else: (-1, 1))
func bottomRightDiagonal(color: PieceColor): Location {.inline.} = (if color == White: (1, 1) else: (-1, -1))
func leftSide(color: PieceColor): Location {.inline.} = (if color == White: (0, -1) else: (0, 1))
func rightSide(color: PieceColor): Location {.inline.} = (if color == White: (0, 1) else: (0, -1))
func topSide(color: PieceColor): Location {.inline.} = (if color == White: (-1, 0) else: (1, 0))
func bottomSide(color: PieceColor): Location {.inline.} = (if color == White: (1, 0) else: (-1, 0))
func forward(color: PieceColor): Location {.inline.} = (if color == White: (-1, 0) else: (1, 0))
func doublePush(color: PieceColor): Location {.inline.} = (if color == White: (-2, 0) else: (2, 0))
func longCastleKing: Location {.inline.} =  (0, -2)
func shortCastleKing: Location {.inline.} = (0, 2)
func longCastleRook: Location {.inline.} = (0, 3)
func shortCastleRook: Location {.inline.} = (0, -2)
func kingSideRook(color: PieceColor): Location {.inline.} = (if color == White: (7, 7) else: (0, 7))
func queenSideRook(color: PieceColor): Location {.inline.} = (if color == White: (7, 0) else: (0, 0))


func bottomLeftKnightMove(color: PieceColor, long: bool = true): Location {.inline.} = 
    if color == White: 
        if long:
            return (2, -1)
        else:
            return (1, -2)
    elif color == Black:
        if long:
            return (-2, 1)
        else:
            return (1, -2)


func bottomRightKnightMove(color: PieceColor, long: bool = true): Location {.inline.} = 
    if color == White: 
        if long:
            return (2, 1)
        else:
            return (1, 2)
    elif color == Black:
        if long:
            return (-2, -1)
        else:
            return (-1, -2)


func topLeftKnightMove(color: PieceColor, long: bool = true): Location {.inline.} = 
    if color == White: 
        if long:
            return (-2, -1)
        else:
            return (-1, -2)
    elif color == Black:
        if long:
            return (2, 1)
        else:
            return (1, 2)


func topRightKnightMove(color: PieceColor, long: bool = true): Location {.inline.} = 
    if color == White: 
        if long:
            return (-2, 1)
        else:
            return (-1, 2)
    elif color == Black:
        if long:
            return (2, -1)
        else:
            return (-1, 2)


func getActiveColor*(self: ChessBoard): PieceColor {.inline.}  =
    ## Returns the currently active color
    ## (turn of who has to move)
    return self.position.turn


func getEnPassantTarget*(self: ChessBoard): Location =
    ## Returns the current en passant target square
    return self.position.enPassantSquare.targetSquare


func getMoveCount*(self: ChessBoard): int =
    ## Returns the number of full moves that
    ## have been played
    return self.position.fullMoveCount


func getHalfMoveCount*(self: ChessBoard): int {.inline.} =
    ## Returns the current number of half-moves
    ## since the last irreversible move
    return self.position.halfMoveClock


func getStartRow(piece: Piece): int {.inline.} =
    ## Retrieves the starting row of
    ## the given piece inside our 8x8
    ## grid
    case piece.color:
        of None:
            return -1
        of White:
            case piece.kind:
                of Pawn:
                    return 6
                else:
                    return 7
        of Black:
            case piece.kind:
                of Pawn:
                    return 1
                else:
                    return 0


func getLastRow(color: PieceColor): int {.inline.} =
    ## Retrieves the location of the last
    ## row relative to the given color
    case color:
        of White:
            return 0
        of Black:
            return 7
        else:
            return -1


proc newChessboard: ChessBoard =
    ## Returns a new, empty chessboard
    new(result)
    # Turns our flat sequence into an 8x8 grid
    result.grid = newMatrixFromSeq[Piece](empty, (8, 8))
    result.position = Position(attacked: (@[], @[]),
                               enPassantSquare: emptyMove(),
                               move: emptyMove(),
                               turn: White,
                               fullMoveCount: 1,
                               pieces: (white: (king: emptyLocation(), 
                                                queens: @[], 
                                                rooks: @[], 
                                                bishops: @[],
                                                knights: @[],
                                                pawns: @[]),
                                        black: (king: emptyLocation(),
                                                queens: @[],
                                                rooks: @[],
                                                bishops: @[],
                                                knights: @[],
                                                pawns: @[])))



proc newChessboardFromFEN*(state: string): ChessBoard =
    ## Initializes a chessboard with the
    ## state encoded by the given FEN string
    result = newChessboard()
    var
        # Current location in the grid
        row: int8 = 0
        column: int8 = 0
        # Current section in the FEN string
        section = 0
        # Current index into the FEN string
        index = 0
        # Temporary variable to store the piece
        piece: Piece
    # See https://en.wikipedia.org/wiki/Forsyth%E2%80%93Edwards_Notation
    while index <= state.high():
        var c = state[index]
        if c == ' ':
            # Next section
            inc(section)
            inc(index)
            continue
        case section:
            of 0:
                # Piece placement data
                case c.toLowerAscii():
                    # Piece
                    of 'r', 'n', 'b', 'q', 'k', 'p':
                        # We know for a fact these values are in our 
                        # enumeration, so all is good
                        {.push.}
                        {.warning[HoleEnumConv]:off.}
                        piece = Piece(kind: PieceKind(c.toLowerAscii()), color: if c.isUpperAscii(): White else: Black)
                        {.pop.}
                        case piece.color:
                            of Black:
                                case piece.kind:
                                    of Pawn:
                                        result.position.pieces.black.pawns.add((row, column))
                                    of Bishop:
                                        result.position.pieces.black.bishops.add((row, column))
                                    of Knight:
                                        result.position.pieces.black.knights.add((row, column))
                                    of Rook:
                                        result.position.pieces.black.rooks.add((row, column))
                                    of Queen:
                                        result.position.pieces.black.queens.add((row, column))
                                    of King:
                                        result.position.pieces.black.king = (row, column)
                                    else:
                                        discard
                            of White:
                                case piece.kind:
                                    of Pawn:
                                        result.position.pieces.white.pawns.add((row, column))
                                    of Bishop:
                                        result.position.pieces.white.bishops.add((row, column))
                                    of Knight:
                                        result.position.pieces.white.knights.add((row, column))
                                    of Rook:
                                        result.position.pieces.white.rooks.add((row, column))
                                    of Queen:
                                        result.position.pieces.white.queens.add((row, column))
                                    of King:
                                        result.position.pieces.white.king = (row, column)
                                    else:
                                        discard
                            else:
                                discard
                        result.grid[row, column] = piece
                        inc(column)
                    of '/':
                        # Next row
                        inc(row)
                        column = 0
                    of '0'..'9':
                        # Skip x columns
                        let x = int(uint8(c) - uint8('0'))
                        if x > 8:
                            raise newException(ValueError, "invalid skip value (> 8) in FEN string")
                        column += int8(x)
                    else:
                        raise newException(ValueError, "invalid piece identifier in FEN string")
            of 1:
                # Active color
                case c:
                    of 'w':
                        result.position.turn = White
                    of 'b':
                        result.position.turn = Black
                    else:
                        raise newException(ValueError, "invalid active color identifier in FEN string")
            of 2:
                # Castling availability
                case c:
                    of '-':
                        # Neither side can castle anywhere: do nothing,
                        # as the castling metadata is set to this state
                        # by default
                        discard
                    of 'K':
                        result.position.castlingAvailable.white.king = true
                    of 'Q':
                        result.position.castlingAvailable.white.queen = true
                    of 'k':
                        result.position.castlingAvailable.black.king = true
                    of 'q':
                        result.position.castlingAvailable.black.queen = true
                    else:
                        raise newException(ValueError, "invalid castling availability in FEN string")
            of 3:
                # En passant target square
                case c:
                    of '-':
                        # Field is already uninitialized to the correct state
                        discard
                    else:
                        result.position.enPassantSquare.targetSquare = state[index..index+1].algebraicToLocation()
                        # Just for cleanliness purposes, we fill in the other metadata as
                        # well
                        result.position.enPassantSquare.piece.color = result.getActiveColor()
                        result.position.enPassantSquare.piece.kind = Pawn
                        # Square metadata is 2 bytes long
                        inc(index)
            of 4:
                # Halfmove clock
                var s = ""
                while not state[index].isSpaceAscii():
                    s.add(state[index])
                    inc(index)
                # Backtrack so the space is seen by the
                # next iteration of the loop
                dec(index)
                result.position.halfMoveClock = parseInt(s).int8
            of 5:
                # Fullmove number
                var s = ""
                while index <= state.high():
                    s.add(state[index])
                    inc(index)
                result.position.fullMoveCount = parseInt(s).int8
            else:
                raise newException(ValueError, "too many fields in FEN string")
        inc(index)
    result.updateAttackedSquares()



proc newDefaultChessboard*: ChessBoard =
    ## Initializes a chessboard with the
    ## starting position
    return newChessboardFromFEN("rnbqkbnr/pppppppp/8/8/8/8/PPPPPPPP/RNBQKBNR w KQkq - 0 1")


proc countPieces*(self: ChessBoard, kind: PieceKind, color: PieceColor): int =
    ## Counts the number of pieces with
    ## the given color and type
    case color:
        of White:
            case kind:
                of Pawn:
                    return self.position.pieces.white.pawns.len()
                of Bishop:
                    return self.position.pieces.white.bishops.len()
                of Knight:
                    return self.position.pieces.white.knights.len()
                of Rook:
                    return self.position.pieces.white.rooks.len()
                of Queen:
                    return self.position.pieces.white.queens.len()
                of King:
                    # There shall be only one, forever
                    return 1
                else:
                    discard
        of Black:
            case kind:
                of Pawn:
                    return self.position.pieces.black.pawns.len()
                of Bishop:
                    return self.position.pieces.black.bishops.len()
                of Knight:
                    return self.position.pieces.black.knights.len()
                of Rook:
                    return self.position.pieces.black.rooks.len()
                of Queen:
                    return self.position.pieces.black.queens.len()
                of King:
                    # In perpetuity
                    return 1
                else:
                    discard        
        of None:
            raise newException(ValueError, "invalid piece type")


proc countPieces*(self: ChessBoard, piece: Piece): int =
    ## Returns the number of pieces on the board that
    ## are of the same type and color of the given piece
    return self.countPieces(piece.kind, piece.color)


func rankToColumn(rank: int): int8 =
    ## Converts a chess rank (1-indexed) 
    ## into a 0-indexed column value for our 
    ## board. This converter is necessary because
    ## chess positions are indexed differently with
    ## respect to our internal representation
    const indeces: array[8, int8] = [7, 6, 5, 4, 3, 2, 1, 0]
    return indeces[rank - 1]


func rowToRank(row: int): int =
    const indeces = [8, 7, 6, 5, 4, 3, 2, 1]
    return indeces[row]


proc algebraicToLocation*(s: string): Location =
    ## Converts a square location from algebraic
    ## notation to its corresponding row and column
    ## in the chess grid (0 indexed)
    if len(s) != 2:
        raise newException(ValueError, "algebraic position must be of length 2")

    var s = s.toLowerAscii()
    if s[0] notin 'a'..'h':
        raise newException(ValueError, &"algebraic position has invalid first character ('{s[0]}')")
    if s[1] notin '1'..'8':
        raise newException(ValueError, &"algebraic position has invalid second character ('{s[1]}')")

    let rank = int8(uint8(s[0]) - uint8('a'))
    # Convert the file character to a number
    let file = rankToColumn(int8(uint8(s[1]) - uint8('0')))
    return (file, rank)


func locationToAlgebraic*(loc: Location): string {.inline.} =
    ## Converts a location from our internal row, column
    ## notation to a square in algebraic notation
    return &"{char(uint8(loc.col) + uint8('a'))}{rowToRank(loc.row)}"


func getPiece*(self: ChessBoard, loc: Location): Piece =
    ## Gets the piece at the given location
    return self.grid[loc.row, loc.col]


func getPiece*(self: ChessBoard, square: string): Piece =
    ## Gets the piece on the given square
    ## in algebraic notation
    return self.getPiece(square.algebraicToLocation())


func isCapture*(move: Move): bool {.inline.} =
    ## Returns whether the given move is a capture
    ## or not
    return move.flag in [Capture, EnPassant]


func isPromotion*(move: Move): bool {.inline.} =
    ## Returns whrther the given move is a 
    ## pawn promotion or not
    return move.flag in [PromoteToBishop, PromoteToKnight, PromoteToRook, PromoteToQueen]


proc inCheck*(self: ChessBoard, color: PieceColor = None): bool =
    ## Returns whether the given color's
    ## king is in check. If the color is
    ## set to None, checks are checked
    ## for the active color's king
    var color = color
    if color == None:
        color = self.getActiveColor()
    case color:
        of White:
            return self.isAttacked(self.position.pieces.white.king, Black)
        of Black:
            return self.isAttacked(self.position.pieces.black.king, White)
        else:
            # Unreachable
            discard


proc canCastle*(self: ChessBoard, color: PieceColor = None): tuple[queen, king: bool] {.inline.} =
    ## Returns the sides on which castling is allowed
    ## for the given color. If the color is Empty, the
    ## currently active color is used
    var color = color
    if color == None:
        color = self.getActiveColor()
    # If the rooks or king have been moved, castling
    # rights have been lost
    case color:
        of White:
            result.king = self.position.castlingAvailable.white.king
            result.queen = self.position.castlingAvailable.white.queen
        of Black:
            result.king = self.position.castlingAvailable.black.king
            result.queen = self.position.castlingAvailable.black.queen
        of None:
            # Unreachable
            discard
    if result.king or result.queen:
        var 
            loc: Location
            queenSide: Location
            kingSide: Location
        if self.inCheck(color):
            # King can not castle out of check
            return (false, false)
        # If the path between the king and rook on a given side is blocked or any of the
        # squares where the king would travel to are attacked by the opponent,
        # then castling is (temporarily) prohibited on that side
        case color:
            of White:
                loc = self.position.pieces.white.king
                queenSide = color.leftSide()
                kingSide = color.rightSide()
            of Black:
                loc = self.position.pieces.black.king
                queenSide = color.rightSide()
                kingSide = color.leftSide()
            of None:
                # Unreachable
                discard

        if result.king:
            # Short castle
            var 
                location = loc
                otherPiece: Piece
            while true:
                location = location + kingSide
                if not location.isValid():
                    break
                otherPiece = self.grid[location.row, location.col]

                if otherPiece.color == None:
                    continue

                if otherPiece.color == color.opposite() or otherPiece.kind != Rook or self.isAttacked(location, color.opposite()):
                    result.king = false
                    break
                if location == color.kingSideRook():
                    break

        if result.queen:
            # Long castle
            var 
                location = loc
                otherPiece: Piece
            while true:
                location = location + queenSide
                if not location.isValid():
                    break
                otherPiece = self.grid[location.row, location.col]

                if otherPiece.color == None:
                    continue

                if otherPiece.color == color.opposite() or otherPiece.kind != Rook or self.isAttacked(location, color.opposite()):
                    result.king = false
                    break
                if location == color.queenSideRook():
                    break


proc generatePawnMoves(self: ChessBoard, location: Location): seq[Move] =
    ## Generates the possible moves for the pawn in the given
    ## location
    var 
        piece = self.grid[location.row, location.col]
        locations: seq[Location] = @[]
        flags: seq[MoveFlag] = @[]
    doAssert piece.kind == Pawn, &"generatePawnMoves called on a {piece.kind}"
    # Pawns can move forward one square
    let forward = (piece.color.forward() + location)
    # Only if the square is empty though
    if forward.isValid() and self.grid[forward.row, forward.col].color == None:
        locations.add(forward)
        flags.add(Default)
    # If the pawn is on its first rank, it can push two squares
    if location.row == piece.getStartRow():
        let double = location + piece.color.doublePush()
        # Check that both squares are empty
        if double.isValid() and self.grid[forward.row, forward.col].color == None and self.grid[double.row, double.col].color == None:
            locations.add(double)
            flags.add(DoublePush)
    # If the target is the en passant square and the piece under en passant
    # is of the opposite color of the pawn being moved, then we check if we
    # can do an en passant capture
    if self.position.enPassantSquare.piece.color == piece.color.opposite:
        if abs(self.position.enPassantSquare.targetSquare.col - location.col) == 1 and abs(self.position.enPassantSquare.targetSquare.row - location.row) == 1:
            # Only viable if the piece is on the front diagonal of the target
            locations.add(self.position.enPassantSquare.targetSquare)
            flags.add(EnPassant)
    # They can also move on either diagonal one
    # square, but only to capture
    var diagonal = location + piece.color.topRightDiagonal()
    if diagonal.isValid() and self.grid[diagonal.row, diagonal.col].color == piece.color.opposite() and self.grid[diagonal.row, diagonal.col].kind != King:
        locations.add(diagonal)
        flags.add(Capture)
    diagonal = location + piece.color.topLeftDiagonal()
    if diagonal.isValid() and self.grid[diagonal.row, diagonal.col].color == piece.color.opposite() and self.grid[diagonal.row, diagonal.col].kind != King:
        locations.add(diagonal)
        flags.add(Capture)
    var 
        newLocation: Location
        newLocations: seq[Location]
    let pins = self.getPinnedDirections(location)
    for pin in pins:
        newLocation = location + pin
        # Pin direction is legal
        if newLocation in locations:
            newLocations.add(newLocation)
    if pins.len() > 0:
        locations = newLocations

    var targetPiece: Piece
    for (target, flag) in zip(locations, flags):
        targetPiece = self.grid[target.row, target.col]
        if target.row == piece.color.getLastRow():
            # Pawn reached the other side of the board: generate all potential piece promotions
            for promotionType in [PromoteToKnight, PromoteToBishop, PromoteToRook, PromoteToQueen]:
                result.add(Move(startSquare: location, targetSquare: target, piece: piece, flag: promotionType))
            continue
        result.add(Move(startSquare: location, targetSquare: target, piece: piece, flag: flag))


proc generateSlidingMoves(self: ChessBoard, location: Location): seq[Move] =
    ## Generates moves for the sliding piece in the given location
    let piece = self.grid[location.row, location.col]
    doAssert piece.kind in [Bishop, Rook, Queen], &"generateSlidingMoves called on a {piece.kind}"
    var directions: seq[Location] = @[]

    # Only check in the right directions for the chosen piece
    if piece.kind in [Bishop, Queen]:
        directions.add(piece.color.topLeftDiagonal())
        directions.add(piece.color.topRightDiagonal())
        directions.add(piece.color.bottomLeftDiagonal())
        directions.add(piece.color.bottomRightDiagonal())
    if piece.kind in [Queen, Rook]:
        directions.add(piece.color.topSide())
        directions.add(piece.color.bottomSide())
        directions.add(piece.color.rightSide())
        directions.add(piece.color.leftSide())
    let pinned = self.getPinnedDirections(location)
    if pinned.len() > 0:
        # If a sliding piece is pinned then it can only
        # move along the pinning direction(s)
        directions = pinned
    for direction in directions:
        # Slide in this direction as long as it's possible
        var
            square: Location = location
            otherPiece: Piece
        while true:
            square = square + direction
            # End of board reached
            if not square.isValid():
                break
            otherPiece = self.grid[square.row, square.col]
            # A friendly piece is in the way
            if otherPiece.color == piece.color:
                break
            if otherPiece.color == piece.color.opposite:
                # Target square contains an enemy piece: capture
                # it and stop going any further
                if otherPiece.kind != King:
                    # Can't capture the king
                    result.add(Move(startSquare: location, targetSquare: square, piece: piece, flag: Capture))
                break
            # Target square is empty
            result.add(Move(startSquare: location, targetSquare: square, piece: piece))


proc generateKingMoves(self: ChessBoard, location: Location): seq[Move] =
    ## Generates moves for the king in the given location
    var 
        piece = self.grid[location.row, location.col]
    doAssert piece.kind == King, &"generateKingMoves called on a {piece.kind}"
    var directions: seq[Location] = @[piece.color.topLeftDiagonal(),
                                      piece.color.topRightDiagonal(),
                                      piece.color.bottomRightDiagonal(),
                                      piece.color.bottomLeftDiagonal(),
                                      piece.color.topSide(),
                                      piece.color.bottomSide(),
                                      piece.color.leftSide(),
                                      piece.color.rightSide()]
    # Castling
    let canCastle = self.canCastle(piece.color)
    if canCastle.queen:
        directions.add(longCastleKing())
    if canCastle.king:
        directions.add(shortCastleKing())
    var flag = Default
    for direction in directions:
        # Step in this direction once
        let square: Location = location + direction
        # End of board reached
        if not square.isValid():
            continue
        if direction == longCastleKing():
            flag = CastleLong
        elif direction == shortCastleKing():
            flag = CastleShort
        else:
            flag = Default
        let otherPiece = self.grid[square.row, square.col]
        if otherPiece.color == self.getActiveColor.opposite():
            flag = Capture
        # A friendly piece or the opponent king is in the way,
        # move onto the next direction
        if otherPiece.color == piece.color or otherPiece.kind == King:
            continue
        # Target square is empty or contains an enemy piece:
        # All good for us!
        result.add(Move(startSquare: location, targetSquare: square, piece: piece, flag: flag))


proc generateKnightMoves(self: ChessBoard, location: Location): seq[Move] =
    ## Generates moves for the knight in the given location
    var 
        piece = self.grid[location.row, location.col]
    doAssert piece.kind == Knight, &"generateKnightMoves called on a {piece.kind}"
    var directions: seq[Location] = @[piece.color.bottomLeftKnightMove(),
                                      piece.color.bottomRightKnightMove(),
                                      piece.color.topLeftKnightMove(),
                                      piece.color.topRightKnightMove(),
                                      piece.color.bottomLeftKnightMove(long=false),
                                      piece.color.bottomRightKnightMove(long=false),
                                      piece.color.topLeftKnightMove(long=false),
                                      piece.color.topRightKnightMove(long=false)]
    let pinned = self.getPinnedDirections(location)
    if pinned.len() > 0:
        # Knight is pinned: can't move!
        return @[]
        
    for direction in directions:
        # Jump to this square
        let square: Location = location + direction
        # End of board reached
        if not square.isValid():
            continue
        let otherPiece = self.grid[square.row, square.col]
        # A friendly piece or the opponent king is is in the way
        if otherPiece.color == piece.color or otherPiece.kind == King:
            continue
        if otherPiece.color != None:
            # Target square contains an enemy piece: capture
            # it
            result.add(Move(startSquare: location, targetSquare: square, piece: piece, flag: Capture))
        else:
            # Target square is empty
            result.add(Move(startSquare: location, targetSquare: square, piece: piece))


proc generateMoves(self: ChessBoard, location: Location): seq[Move] =
    ## Returns the list of possible legal chess moves for the
    ## piece in the given location
    let piece = self.grid[location.row, location.col]
    case piece.kind:
        of Queen, Bishop, Rook:
            return self.generateSlidingMoves(location)
        of Pawn:
            return self.generatePawnMoves(location)
        of King:
            return self.generateKingMoves(location)
        of Knight:
            return self.generateKnightMoves(location)
        else:
            return @[]


proc generateAllMoves*(self: ChessBoard): seq[Move] =
    ## Returns the list of all possible legal moves
    ## in the current position
    for i, row in self.grid:
        for j, piece in row:
            if self.grid[i, j].color == self.getActiveColor():
                for move in self.generateMoves((int8(i), int8(j))):
                    result.add(move)


proc getAttackers*(self: ChessBoard, square: Location, color = None): seq[Location] =
    ## Returns all the attackers of the given square
    ## for the given color (a color of None means use
    ## the currently active color)
    var color = color
    if color == None:
        color = self.getActiveColor()
    case color:
        of White:
            for attack in self.position.attacked.black:
                if attack.target == square:
                    result.add(attack.source)
        of Black:
            for attack in self.position.attacked.white:
                if attack.target == square:
                    result.add(attack.source)
        else:
            # Unreachable
            discard        

# We don't use getAttackers because this one only cares about whether
# the square is attacked or not (and can therefore exit earlier than
# getAttackers)
proc isAttacked*(self: ChessBoard, loc: Location, color: PieceColor = None): bool =
    ## Returns whether the given location is attacked
    ## by the given color
    var color = color
    if color == None:
        color = self.getActiveColor().opposite()
    case color:
        of Black:
            for attack in self.position.attacked.black:
                if attack.target == loc:
                    return true
        of White:
            for attack in self.position.attacked.white:
                if attack.target == loc:
                    return true
        of None:
            discard


proc isAttacked*(self: ChessBoard, square: string): bool = 
    ## Returns whether the given square is attacked
    ## by the current
    return self.isAttacked(square.algebraicToLocation())


func addAttack(self: ChessBoard, attack: tuple[source, target: Location], color: PieceColor) {.inline.} =
    if attack.source.isValid() and attack.target.isValid():
        case color:
            of White:
                self.position.attacked.white.add(attack)
            of Black:
                self.position.attacked.black.add(attack)
            else:
                discard


proc getPinnedDirections(self: ChessBoard, loc: Location): seq[Location] =
    let piece = self.grid[loc.row, loc.col]
    case piece.color:
        of None:
            discard
        of White:
            for pin in self.position.pinned.black:
                if pin.target == loc:
                    result.add(pin.direction)
        of Black:
            for pin in self.position.pinned.white:
                if pin.target == loc:
                    result.add(pin.direction)


proc updatePawnAttacks(self: ChessBoard) {.thread.} =
    ## Internal helper of updateAttackedSquares
    for loc in self.position.pieces.white.pawns:
        # Pawns are special in how they capture (i.e. the
        # squares they can move to do not match the squares
        # they can capture on. Sneaky fucks)
        self.addAttack((loc, loc + White.topRightDiagonal()), White)
        self.addAttack((loc, loc + White.topLeftDiagonal()), White)
    # We do the same thing for black
    for loc in self.position.pieces.black.pawns:
        self.addAttack((loc, loc + Black.topRightDiagonal()), Black)
        self.addAttack((loc, loc + Black.topLeftDiagonal()), Black)


proc updateKingAttacks(self: ChessBoard) =
    ## Internal helper of updateAttackedSquares
    var king = self.position.pieces.white.king
    self.addAttack((king, king + White.topRightDiagonal()), White)
    self.addAttack((king, king + White.topLeftDiagonal()), White)
    self.addAttack((king, king + White.bottomLeftDiagonal()), White)
    self.addAttack((king, king + White.bottomRightDiagonal()), White)
    king = self.position.pieces.black.king
    self.addAttack((king, king + Black.topRightDiagonal()), Black)
    self.addAttack((king, king + Black.topLeftDiagonal()), Black)
    self.addAttack((king, king + Black.bottomLeftDiagonal()), Black)
    self.addAttack((king, king + Black.bottomRightDiagonal()), Black)


proc updateKnightAttacks(self: ChessBoard) =
    ## Internal helper of updateAttackedSquares
    for loc in self.position.pieces.white.knights:
        self.addAttack((loc, loc + White.topLeftKnightMove()), White)
        self.addAttack((loc, loc + White.topRightKnightMove()), White)
        self.addAttack((loc, loc + White.bottomLeftKnightMove()), White)
        self.addAttack((loc, loc + White.bottomRightKnightMove()), White)
        self.addAttack((loc, loc + White.topLeftKnightMove(long=false)), White)
        self.addAttack((loc, loc + White.topRightKnightMove(long=false)), White)
        self.addAttack((loc, loc + White.bottomLeftKnightMove(long=false)), White)
        self.addAttack((loc, loc + White.bottomRightKnightMove(long=false)), White)

    for loc in self.position.pieces.black.knights:
        self.addAttack((loc, loc + Black.topLeftKnightMove()), Black)
        self.addAttack((loc, loc + Black.topRightKnightMove()), Black)
        self.addAttack((loc, loc + Black.bottomLeftKnightMove()), Black)
        self.addAttack((loc, loc + Black.bottomRightKnightMove()), Black)
        self.addAttack((loc, loc + Black.topLeftKnightMove(long=false)), Black)
        self.addAttack((loc, loc + Black.topRightKnightMove(long=false)), Black)
        self.addAttack((loc, loc + Black.bottomLeftKnightMove(long=false)), Black)
        self.addAttack((loc, loc + Black.bottomRightKnightMove(long=false)), Black)


proc getSlidingAttacks(self: ChessBoard, loc: Location): tuple[attacks: Attacked, pins: Pinned] =
    ## Internal helper of updateSlidingAttacks
    var 
        directions: seq[Location] = @[]
    let piece = self.grid[loc.row, loc.col]
    if piece.kind in [Bishop, Queen]:
        directions.add(piece.color.topLeftDiagonal())
        directions.add(piece.color.topRightDiagonal())
        directions.add(piece.color.bottomLeftDiagonal())
        directions.add(piece.color.bottomRightDiagonal())

    if piece.kind in [Queen, Rook]:
        directions.add(piece.color.topSide())
        directions.add(piece.color.bottomSide())
        directions.add(piece.color.rightSide())
        directions.add(piece.color.leftSide())

    for direction in directions:
        var 
            square = loc
            otherPiece: Piece
        # Slide in this direction as long as it's possible
        while true:
            square = square + direction
            # End of board reached
            if not square.isValid():
                break
            otherPiece = self.grid[square.row, square.col]
            # Target square is attacked (even if a friendly piece
            # is present, because in this case we're defending
            # it)
            result.attacks.add((loc, square))
            # Empty square, keep going
            if otherPiece.color == None:
                continue
            if otherPiece.color == piece.color.opposite and otherPiece.kind != King:
                # We found an enemy piece that is not
                # the enemy king. We don't break out
                # immediately because we first want 
                # to check if we've pinned a piece
                var 
                    otherSquare: Location = square
                    behindPiece: Piece
                while true:
                    otherSquare = otherSquare + direction
                    if not otherSquare.isValid():
                        break
                    behindPiece = self.grid[otherSquare.row, otherSquare.col]
                    if behindPiece.color == None:
                        continue
                    if behindPiece.color == piece.color.opposite and behindPiece.kind == King:
                        # The enemy king is behind this enemy piece: pin it in
                        # this direction relative to them (that's why we have the
                        # minus sign: up for us is down for them and vice versa)
                        result.pins.add((loc, square, -direction))
                    else:
                        break   
            break


proc updateSlidingAttacks(self: ChessBoard) =
    ## Internal helper of updateAttackedSquares
    
    var data: tuple[attacks: Attacked, pins: Pinned]
    for loc in self.position.pieces.white.bishops:
        data = self.getSlidingAttacks(loc)
        self.position.attacked.white.extend(data.attacks)
        self.position.pinned.white.extend(data.pins)
    for loc in self.position.pieces.white.rooks:
        data = self.getSlidingAttacks(loc)
        self.position.attacked.white.extend(data.attacks)
        self.position.pinned.white.extend(data.pins)
    for loc in self.position.pieces.white.queens:
        data = self.getSlidingAttacks(loc)
        self.position.attacked.white.extend(data.attacks)
        self.position.pinned.white.extend(data.pins)
    for loc in self.position.pieces.black.bishops:
        data = self.getSlidingAttacks(loc)
        self.position.attacked.black.extend(data.attacks)
        self.position.pinned.black.extend(data.pins)
    for loc in self.position.pieces.black.rooks:
        data = self.getSlidingAttacks(loc)
        self.position.attacked.black.extend(data.attacks)
        self.position.pinned.black.extend(data.pins)
    for loc in self.position.pieces.black.queens:
        data = self.getSlidingAttacks(loc)
        self.position.attacked.black.extend(data.attacks)
        self.position.pinned.black.extend(data.pins)


proc updateAttackedSquares(self: ChessBoard) =
    ## Updates internal metadata about which squares
    ## are attacked
    
    self.position.attacked.white.setLen(0)
    self.position.attacked.black.setLen(0)
    # Pawns
    self.updatePawnAttacks()
    # Sliding pieces
    self.updateSlidingAttacks()
    # Knights
    self.updateKnightAttacks()
    # Kings
    self.updateKingAttacks()


proc removePiece(self: ChessBoard, location: Location, attack: bool = true) =
    ## Removes a piece from the board, updating necessary
    ## metadata
    var piece = self.grid[location.row, location.col]
    self.grid[location.row, location.col] = emptyPiece()
    case piece.color:
        of White:
            case piece.kind:
                of Pawn:
                    self.position.pieces.white.pawns.delete(self.position.pieces.white.pawns.find(location))
                of Bishop:
                    self.position.pieces.white.pawns.delete(self.position.pieces.white.bishops.find(location))
                of Knight:
                    self.position.pieces.white.pawns.delete(self.position.pieces.white.knights.find(location))
                of Rook:
                    self.position.pieces.white.rooks.delete(self.position.pieces.white.rooks.find(location))
                of Queen:
                    self.position.pieces.white.queens.delete(self.position.pieces.white.queens.find(location))
                of King:
                    doAssert false, "removePiece: attempted to remove the white king"
                else:
                    discard 
        of Black:
            case piece.kind:
                of Pawn:
                    self.position.pieces.black.pawns.delete(self.position.pieces.black.pawns.find(location))
                of Bishop:
                    self.position.pieces.black.bishops.delete(self.position.pieces.black.bishops.find(location))
                of Knight:
                    self.position.pieces.black.knights.delete(self.position.pieces.black.knights.find(location))
                of Rook:
                    self.position.pieces.black.rooks.delete(self.position.pieces.black.rooks.find(location))
                of Queen:
                    self.position.pieces.black.queens.delete(self.position.pieces.black.queens.find(location))
                of King:
                    doAssert false, "removePiece: attempted to remove the black king"
                else:
                    discard
        else:
            discard
    if attack:
        self.updateAttackedSquares()


proc movePiece(self: ChessBoard, move: Move, attack: bool = true) =
    ## Internal helper to move a piece. If attack
    ## is set to false, then this function does
    ## not update attacked squares metadata, just 
    ## positional info and the grid itself
    case move.piece.color:
        of White:
            case move.piece.kind:
                of Pawn:
                    # The way things are structured, we don't care about the order
                    # of this list, so we can add and remove entries as we please
                    self.position.pieces.white.pawns.delete(self.position.pieces.white.pawns.find(move.startSquare))
                    self.position.pieces.white.pawns.add(move.targetSquare)
                of Bishop:
                    self.position.pieces.white.bishops.delete(self.position.pieces.white.bishops.find(move.startSquare))
                    self.position.pieces.white.bishops.add(move.targetSquare)
                of Knight:
                    self.position.pieces.white.knights.delete(self.position.pieces.white.knights.find(move.startSquare))
                    self.position.pieces.white.knights.add(move.targetSquare)
                of Rook:
                    self.position.pieces.white.rooks.delete(self.position.pieces.white.rooks.find(move.startSquare))
                    self.position.pieces.white.rooks.add(move.targetSquare)
                of Queen:
                    self.position.pieces.white.queens.delete(self.position.pieces.white.queens.find(move.startSquare))
                    self.position.pieces.white.queens.add(move.targetSquare)
                of King:
                    self.position.pieces.white.king = move.targetSquare
                else:
                    discard
        of Black:
            case move.piece.kind:
                of Pawn:
                    self.position.pieces.black.pawns.delete(self.position.pieces.black.pawns.find(move.startSquare))
                    self.position.pieces.black.pawns.add(move.targetSquare)
                of Bishop:
                    self.position.pieces.black.bishops.delete(self.position.pieces.black.bishops.find(move.startSquare))
                    self.position.pieces.black.bishops.add(move.targetSquare)
                of Knight:
                    self.position.pieces.black.knights.delete(self.position.pieces.black.knights.find(move.startSquare))
                    self.position.pieces.black.knights.add(move.targetSquare)
                of Rook:
                    self.position.pieces.black.rooks.delete(self.position.pieces.black.rooks.find(move.startSquare))
                    self.position.pieces.black.rooks.add(move.targetSquare)
                of Queen:
                    self.position.pieces.black.queens.delete(self.position.pieces.black.queens.find(move.startSquare))
                    self.position.pieces.black.queens.add(move.targetSquare)
                of King:
                    self.position.pieces.black.king = move.targetSquare
                else:
                    discard
        else:
            discard
    # Empty out the starting square
    self.grid[move.startSquare.row, move.startSquare.col] = emptyPiece()
    # Actually move the piece
    self.grid[move.targetSquare.row, move.targetSquare.col] = move.piece
    if attack:
        self.updateAttackedSquares()


proc movePiece(self: ChessBoard, startSquare, targetSquare: Location, attack: bool = true) =
    ## Like the other movePiece(), but with two locations
    self.movePiece(Move(startSquare: startSquare, targetSquare: targetSquare,
                        piece: self.grid[startSquare.row, startSquare.col],
                        ),
                    attack
                  )


proc updateLocations(self: ChessBoard, move: Move) =
    ## Internal helper to update the position of
    ## the pieces on the board after a move
    if move.isCapture():
        self.position.captured = self.grid[move.targetSquare.row, move.targetSquare.col]
        self.removePiece(move.targetSquare, attack=false)

    # Update the positional metadata of the moving piece
    self.movePiece(move)


proc doMove(self: ChessBoard, move: Move) =
    ## Internal function called by makeMove after
    ## performing legality checks on the given move. Can
    ## be used in performance-critical paths where
    ## a move is already known to be legal

    # Final checks
    
    # Record the final move in the position
    self.position.move = move

    # Needed to detect draw by the 50 move rule
    var 
        halfMoveClock = self.position.halfMoveClock
        fullMoveCount = self.position.fullMoveCount
        castlingAvailable = self.position.castlingAvailable
    if move.piece.kind == Pawn or move.isCapture():
        halfMoveClock = 0
    else:
        inc(halfMoveClock)
    if move.piece.color == Black:
        inc(fullMoveCount)
    # Castling check: have the rooks moved?
    if move.piece.kind == Rook:
        case move.piece.color:
            of White:
                if move.startSquare.row == move.piece.getStartRow():
                    if move.startSquare.col == 0:
                        # Queen side
                        castlingAvailable.white.queen = false
                    elif move.startSquare.col == 7:
                        # King side
                        castlingAvailable.white.king = false
            of Black:
                if move.startSquare.row == move.piece.getStartRow():
                    if move.startSquare.col == 0:
                        # Queen side
                        castlingAvailable.black.queen = false
                    elif move.startSquare.col == 7:
                        # King side
                        castlingAvailable.black.king = false
            else:
                discard
    # Has a rook been captured?
    if move.isCapture():
        let piece = self.grid[move.targetSquare.row, move.targetSquare.col]
        if piece.kind == Rook:
            case piece.color:
                of White:
                    if move.targetSquare == piece.color.queenSideRook():
                        # Queen side
                        castlingAvailable.white.queen = false
                    elif move.targetSquare == piece.color.kingSideRook():
                        # King side
                        castlingAvailable.white.king = false
                of Black:
                    if move.targetSquare == piece.color.queenSideRook():
                        # Queen side
                        castlingAvailable.black.queen = false
                    elif move.targetSquare == piece.color.kingSideRook():
                        # King side
                        castlingAvailable.black.king = false
                else:
                    # Unreachable
                    discard
    # Has the king moved?
    if move.piece.kind == King:
        case move.piece.color:
            of White:
                castlingAvailable.white.king = false
                castlingAvailable.white.queen = false
            of Black:
                castlingAvailable.black.king = false
                castlingAvailable.black.queen = false
            else:
                discard
    if move.isPromotion():
        # Move is a pawn promotion: get rid of then pawn
        # and spawn a new piece
        self.removePiece(move.startSquare)
        case move.flag:
            of PromoteToBishop:
                self.spawnPiece(move.targetSquare, Piece(kind: Bishop, color: move.piece.color))
            of PromoteToKnight:
                self.spawnPiece(move.targetSquare, Piece(kind: Knight, color: move.piece.color))
            of PromoteToRook:
                self.spawnPiece(move.targetSquare, Piece(kind: Rook, color: move.piece.color))
            of PromoteToQueen:
                self.spawnPiece(move.targetSquare, Piece(kind: Queen, color: move.piece.color))
            else:
                discard
    let previous = self.position
    # Record final position for future reference
    self.positions.add(previous)
    # Create new position
    self.position = Position(plyFromRoot: self.position.plyFromRoot + 1,
                            halfMoveClock: halfMoveClock,
                            fullMoveCount: fullMoveCount,
                            captured: emptyPiece(),
                            turn: self.getActiveColor().opposite,
                            castlingAvailable: castlingAvailable,
                            # Updated at the next call to doMove()
                            move: emptyMove(),
                            pieces: previous.pieces,
                            )

    var location: Location
    if move.flag in [CastleShort, CastleLong]:
        # Revoke all castling rights for the moving king
        case move.piece.color:
            of White:
                self.position.castlingAvailable.white.king = false
                self.position.castlingAvailable.white.queen = false
            of Black:
                self.position.castlingAvailable.black.king = false
                self.position.castlingAvailable.black.queen = false
            else:
                discard
        # Move the rook onto the
        # correct file
        var 
            location: Location
            target: Location
        if move.flag == CastleShort:
            location = move.piece.color.kingSideRook()
            target = shortCastleRook()
        else:
            location = move.piece.color.queenSideRook()
            target = longCastleRook()
        let rook = self.grid[location.row, location.col]
        let move = Move(startSquare: location, targetSquare: location + target, piece: rook, flag: move.flag)
        self.movePiece(move, attack=false)

    # Update position and attack metadata
    self.updateLocations(move)
    
    # Check for double pawn push
    if move.flag == DoublePush:
        self.position.enPassantSquare = Move(piece: move.piece,
                                      startSquare: (move.startSquare.row, move.startSquare.col),
                                      targetSquare: move.targetSquare + move.piece.color.bottomSide())
    else:
        self.position.enPassantSquare = emptyMove()


proc spawnPiece(self: ChessBoard, location: Location, piece: Piece) =
    ## Internal helper to "spawn" a given piece at the given
    ## location. Note that this will overwrite whatever piece
    ## was previously located there: use with caution. Does
    ## not automatically update the attacked square metadata
    ## or other positional information
    case piece.color:
        of White:
            case piece.kind:
                of Pawn:
                    self.position.pieces.white.pawns.add(location)
                of Knight:
                    self.position.pieces.white.knights.add(location)
                of Bishop:
                    self.position.pieces.white.bishops.add(location)
                of Rook:
                    self.position.pieces.white.rooks.add(location)
                of Queen:
                    self.position.pieces.white.queens.add(location)
                of King:
                    self.position.pieces.white.king = location
                else:
                    discard
        of Black:
            case piece.kind:
                of Pawn:
                    self.position.pieces.black.pawns.add(location)
                of Knight:
                    self.position.pieces.black.knights.add(location)
                of Bishop:
                    self.position.pieces.black.bishops.add(location)
                of Rook:
                    self.position.pieces.black.rooks.add(location)
                of Queen:
                    self.position.pieces.black.queens.add(location)
                of King:
                    self.position.pieces.black.king = location
                else:
                    discard
        else:
            # Unreachable
            discard
    self.grid[location.row, location.col] = piece


proc resetBoard*(self: ChessBoard) =
    ## Resets the internal grid representation
    ## according to the positional data stored
    ## in the chessboard. Warning: this can be
    ## expensive, especially in critical paths
    ## or tight loops
    self.grid = newMatrixFromSeq[Piece](empty, (8, 8))
    for loc in self.position.pieces.white.pawns:
        self.grid[loc.row, loc.col] = Piece(color: White, kind: Pawn)
    for loc in self.position.pieces.black.pawns:
        self.grid[loc.row, loc.col] = Piece(color: Black, kind: Pawn)
    for loc in self.position.pieces.white.bishops:
        self.grid[loc.row, loc.col] = Piece(color: White, kind: Bishop)
    for loc in self.position.pieces.black.bishops:
        self.grid[loc.row, loc.col] = Piece(color: Black, kind: Bishop)
    for loc in self.position.pieces.white.knights:
        self.grid[loc.row, loc.col] = Piece(color: White, kind: Knight)
    for loc in self.position.pieces.black.knights:
        self.grid[loc.row, loc.col] = Piece(color: Black, kind: Knight)
    for loc in self.position.pieces.white.rooks:
        self.grid[loc.row, loc.col] = Piece(color: White, kind: Rook)
    for loc in self.position.pieces.black.rooks:
        self.grid[loc.row, loc.col] = Piece(color: Black, kind: Rook)
    for loc in self.position.pieces.white.queens:
        self.grid[loc.row, loc.col] = Piece(color: White, kind: Queen)
    for loc in self.position.pieces.black.queens:
        self.grid[loc.row, loc.col] = Piece(color: Black, kind: Queen)
    self.grid[self.position.pieces.white.king.row, self.position.pieces.white.king.col] = Piece(color: White, kind: King)
    self.grid[self.position.pieces.black.king.row, self.position.pieces.black.king.col] = Piece(color: Black, kind: King)


proc undoMove*(self: ChessBoard, move: Move) =
    ## Undoes the given move
    if self.positions.len() == 0:
        return
    let previous = self.position
    var position = self.positions[^1]
    while position.move != move:
        discard self.positions.pop()
        position = self.positions[^1]
    
    self.position = position
    self.grid[move.startSquare.row, move.startSquare.col] = move.piece
    if move.isCapture():
        self.grid[move.targetSquare.row, move.targetSquare.col] = previous.captured
    else:
        self.grid[move.targetSquare.row, move.targetSquare.col] = emptyPiece()
    # Reset the location of the rook in the
    # grid (it's already correct in the piece
    # list)
    if move.flag == CastleLong:
        let 
            rookOld = move.targetSquare + move.piece.color.rightSide()
            rookNew = move.piece.color.queenSideRook()
        self.grid[rookNew.row, rookNew.col] = self.grid[rookOld.row, rookOld.col]
        self.grid[rookOld.row, rookOld.col] = emptyPiece()
    if move.flag == CastleShort:
        let 
            rookOld = move.targetSquare + move.piece.color.leftSide()
            rookNew = move.piece.color.kingSideRook()
        self.grid[rookNew.row, rookNew.col] = self.grid[rookOld.row, rookOld.col]
        self.grid[rookOld.row, rookOld.col] = emptyPiece()


proc isLegal(self: ChessBoard, move: Move): bool {.inline.} =
    ## Returns whether the given move is legal
    return move in self.generateMoves(move.startSquare)


proc makeMove*(self: ChessBoard, move: Move): Move {.discardable.} =
    ## Like the other makeMove(), but with a Move object
    result = move
    self.position.move = move
    if not self.isLegal(move):
        return emptyMove()
    self.doMove(move)
    result = self.position.move


proc makeMove*(self: ChessBoard, startSquare, targetSquare: string): Move {.discardable.} =
    ## Makes a move on the board from the chosen start square to
    ## the chosen target square, ensuring it is legal (turns are
    ## taken into account!). This function returns a Move object: if the move
    ## is legal and has been performed, the fields will be populated properly.
    ## For efficiency purposes, no exceptions are raised if the move is 
    ## illegal, but the move's piece kind will be Empty (its color will be None
    ## too) and the locations will both be set to the tuple (-1, -1)
    var 
        startLocation = startSquare.algebraicToLocation()
        targetLocation = targetSquare.algebraicToLocation()
    result = Move(startSquare: startLocation, targetSquare: targetLocation, piece: self.grid[startLocation.row, startLocation.col])
    return self.makeMove(result)


proc makeMove*(self: ChessBoard, startSquare, targetSquare: Location): Move {.discardable.} =
    ## Like the other makeMove(), but with two locations
    result = Move(startSquare: startSquare, targetSquare: targetSquare, piece: self.grid[startSquare.row, startSquare.col])
    return self.makeMove(result)


proc `$`*(self: ChessBoard): string =
    result &= "- - - - - - - -"
    for i, row in self.grid:
        result &= "\n"
        for piece in row:
            if piece.kind == Empty:
                result &= "x "
                continue
            if piece.color == White:
                result &= &"{char(piece.kind).toUpperAscii()} "
            else:
                result &= &"{char(piece.kind)} "
        result &= &"{rankToColumn(i + 1) + 1}"
    result &= "\n- - - - - - - -"
    result &= "\na b c d e f g h"


proc pretty*(self: ChessBoard): string =
    ## Returns a colorized version of the
    ## board for easier visualization
    result &= "- - - - - - - -"

    for i, row in self.grid:
        result &= "\n"
        for j, piece in row:
            if piece.kind == Empty:
                result &= "\x1b[36;1mx"
                # Avoids the color overflowing
                # onto the numbers
                if j < 7:
                    result &= " \x1b[0m"
                else:
                    result &= "\x1b[0m "
                continue
            if piece.color == White:
                result &= &"\x1b[37;1m{char(piece.kind).toUpperAscii()}\x1b[0m "
            else:
                result &= &"\x1b[30;1m{char(piece.kind)} "
        result &= &"\x1b[33;1m{rankToColumn(i + 1) + 1}\x1b[0m"

    result &= "\n- - - - - - - -"
    result &= "\n\x1b[31;1ma b c d e f g h"
    result &= "\x1b[0m"


proc perft*(self: ChessBoard, ply: int, verbose: bool = false): CountData =
    ## Counts (and debugs) the number of legal positions reached after
    ## the given number of ply
    var verbose = verbose
    if ply == 0:
        result = (1, 0, 0, 0, 0, 0, 0)
    else:
        let moves = self.generateAllMoves()
        if len(moves) == 0:
            inc(result.checkmates)
        for move in moves:
            if verbose:
                let canCastle = self.canCastle(move.piece.color)
                #echo "\x1Bc"
                echo &"Ply: {self.position.plyFromRoot}"
                echo &"Move: {move.startSquare.locationToAlgebraic()}{move.targetSquare.locationToAlgebraic()}, from ({move.startSquare.row}, {move.startSquare.col}) to ({move.targetSquare.row}, {move.targetSquare.col})"
                echo &"Turn: {move.piece.color}"
                echo &"Piece: {move.piece.kind}"
                echo &"Flag: {move.flag}"
                echo &"In check: {(if self.inCheck(): \"yes\" else: \"no\")}"
                echo &"Can castle:\n  - King side: {(if canCastle.king: \"yes\" else: \"no\")}\n  - Queen side: {(if canCastle.queen: \"yes\" else: \"no\")}"
                echo "Before:\n"
                echo self.pretty()
                try:
                    discard readLine(stdin)
                except IOError:
                    discard
                except EOFError:
                    discard
            self.doMove(move)
            case move.flag:
                of Capture:
                    inc(result.captures)
                of CastleShort, CastleLong:
                    inc(result.castles)
                of PromoteToBishop, PromoteToKnight, PromoteToQueen, PromoteToRook:
                    inc(result.promotions)
                of EnPassant:
                    inc(result.enPassant)
                else:
                    discard
            if self.inCheck():
                # Opponent king is in check
                inc(result.checks)
            if verbose:
                echo "Now:\n"
                echo self.pretty()
                try:
                    discard readLine(stdin)
                except IOError:
                    discard
                except EOFError:
                    discard
            let next = self.perft(ply - 1, verbose)
            result.nodes += next.nodes
            result.captures += next.captures
            result.checks += next.checks
            result.promotions += next.promotions
            result.castles += next.castles
            result.enPassant += next.enPassant
            result.checkmates += next.checkmates
            self.undoMove(move)



when isMainModule:
    proc testPiece(piece: Piece, kind: PieceKind, color: PieceColor) =
        doAssert piece.kind == kind and piece.color == color, &"expected piece of kind {kind} and color {color}, got {piece.kind} / {piece.color} instead"

    proc testPieceCount(board: ChessBoard, kind: PieceKind, color: PieceColor, count: int) =
        let pieces = board.countPieces(kind, color)
        doAssert pieces == count, &"expected {count} pieces of kind {kind} and color {color}, got {pieces} instead"

    echo "Running tests"
    var b = newDefaultChessboard()
    # Ensure correct number of pieces
    testPieceCount(b, Pawn, White, 8)
    testPieceCount(b, Pawn, Black, 8)
    testPieceCount(b, Knight, White, 2)
    testPieceCount(b, Knight, Black, 2)
    testPieceCount(b, Bishop, White, 2)
    testPieceCount(b, Bishop, Black, 2)
    testPieceCount(b, Rook, White, 2)
    testPieceCount(b, Rook, Black, 2)
    testPieceCount(b, Queen, White, 1)
    testPieceCount(b, Queen, Black, 1)
    testPieceCount(b, King, White, 1)
    testPieceCount(b, King, Black, 1)
    

    # Ensure pieces are in the correct location

    # Pawns
    for loc in ["a2", "b2", "c2", "d2", "e2", "f2", "g2", "h2"]:
        testPiece(b.getPiece(loc), Pawn, White)
    for loc in ["a7", "b7", "c7", "d7", "e7", "f7", "g7", "h7"]:
        testPiece(b.getPiece(loc), Pawn, Black)
    # Rooks
    testPiece(b.getPiece("a1"), Rook, White)
    testPiece(b.getPiece("h1"), Rook, White)
    testPiece(b.getPiece("a8"), Rook, Black)
    testPiece(b.getPiece("h8"), Rook, Black)
    # Knights
    testPiece(b.getPiece("b1"), Knight, White)
    testPiece(b.getPiece("g1"), Knight, White)
    testPiece(b.getPiece("b8"), Knight, Black)
    testPiece(b.getPiece("g8"), Knight, Black)
    # Bishops
    testPiece(b.getPiece("c1"), Bishop, White)
    testPiece(b.getPiece("f1"), Bishop, White)
    testPiece(b.getPiece("c8"), Bishop, Black)
    testPiece(b.getPiece("f8"), Bishop, Black)
    # Kings
    testPiece(b.getPiece("e1"), King, White)
    testPiece(b.getPiece("e8"), King, Black)
    # Queens
    testPiece(b.getPiece("d1"), Queen, White)
    testPiece(b.getPiece("d8"), Queen, Black)

    when compileOption("profiler"):
        import nimprof
    
    # b = newChessboardFromFEN("fen")
    echo b.perft(4, verbose=true)
    echo "All tests were successful"